Gecko [ waterstats.dev.bestseocompanymiami.com ]

Name	Size	Permission
images	[ DIR ]	drwxr-xr-x
README	2.03 KB	-rw-r--r--
anilabel.tcl	6.51 KB	-rw-r--r--
aniwave.tcl	3.41 KB	-rw-r--r--
arrow.tcl	7.8 KB	-rw-r--r--
bind.tcl	2.88 KB	-rw-r--r--
bitmap.tcl	1.38 KB	-rw-r--r--
browse	1.72 KB	-rwxr-xr-x
button.tcl	1.47 KB	-rw-r--r--
check.tcl	2.22 KB	-rw-r--r--
clrpick.tcl	1.4 KB	-rw-r--r--
colors.tcl	4.88 KB	-rw-r--r--
combo.tcl	1.92 KB	-rw-r--r--
cscroll.tcl	3.31 KB	-rw-r--r--
ctext.tcl	5.88 KB	-rw-r--r--
dialog1.tcl	660 B	-rw-r--r--
dialog2.tcl	613 B	-rw-r--r--
en.msg	3.78 KB	-rw-r--r--
entry1.tcl	1.35 KB	-rw-r--r--
entry2.tcl	2.03 KB	-rw-r--r--
entry3.tcl	5.96 KB	-rw-r--r--
filebox.tcl	2.3 KB	-rw-r--r--
floor.tcl	77.25 KB	-rw-r--r--
fontchoose.tcl	1.71 KB	-rw-r--r--
form.tcl	1.02 KB	-rw-r--r--
goldberg.tcl	55.23 KB	-rw-r--r--
hello	512 B	-rwxr-xr-x
hscale.tcl	1.46 KB	-rw-r--r--
icon.tcl	2.01 KB	-rw-r--r--
image1.tcl	1002 B	-rw-r--r--
image2.tcl	3.27 KB	-rw-r--r--
items.tcl	9.9 KB	-rw-r--r--
ixset	7.88 KB	-rwxr-xr-x
knightstour.tcl	8.93 KB	-rw-r--r--
label.tcl	1.35 KB	-rw-r--r--
labelframe.tcl	1.8 KB	-rw-r--r--
license.terms	2.21 KB	-rw-r--r--
mclist.tcl	4.25 KB	-rw-r--r--
menu.tcl	6.62 KB	-rw-r--r--
menubu.tcl	4.37 KB	-rw-r--r--
msgbox.tcl	1.95 KB	-rw-r--r--
nl.msg	6.59 KB	-rw-r--r--
paned1.tcl	1.08 KB	-rw-r--r--
paned2.tcl	2.19 KB	-rw-r--r--
pendulum.tcl	7.42 KB	-rw-r--r--
plot.tcl	2.69 KB	-rw-r--r--
puzzle.tcl	2.54 KB	-rw-r--r--
radio.tcl	2.69 KB	-rw-r--r--
rmt	5.19 KB	-rwxr-xr-x
rolodex	8.11 KB	-rwxr-xr-x
ruler.tcl	5.09 KB	-rw-r--r--
sayings.tcl	2.22 KB	-rw-r--r--
search.tcl	4.3 KB	-rw-r--r--
spin.tcl	1.78 KB	-rw-r--r--
states.tcl	2 KB	-rw-r--r--
style.tcl	6.78 KB	-rw-r--r--
tclIndex	4.25 KB	-rw-r--r--
tcolor	10.99 KB	-rwxr-xr-x
text.tcl	4.17 KB	-rw-r--r--
textpeer.tcl	2.14 KB	-rw-r--r--
timer	1.07 KB	-rwxr-xr-x
toolbar.tcl	3.19 KB	-rw-r--r--
tree.tcl	3.09 KB	-rw-r--r--
ttkbut.tcl	3.33 KB	-rw-r--r--
ttkmenu.tcl	2.33 KB	-rw-r--r--
ttknote.tcl	2.26 KB	-rw-r--r--
ttkpane.tcl	4.07 KB	-rw-r--r--
ttkprogress.tcl	1.5 KB	-rw-r--r--
ttkscale.tcl	1.39 KB	-rw-r--r--
twind.tcl	10.79 KB	-rw-r--r--
unicodeout.tcl	4.3 KB	-rw-r--r--
vscale.tcl	1.44 KB	-rw-r--r--
widget	22.72 KB	-rwxr-xr-x

Code Editor : mclist.tcl

# mclist.tcl --
#
# This demonstration script creates a toplevel window containing a Ttk
# tree widget configured as a multi-column listbox.

if {![info exists widgetDemo]} {
    error "This script should be run from the \"widget\" demo."
}

package require Tk

set w .mclist
catch {destroy $w}
toplevel $w
wm title $w "Multi-Column List"
wm iconname $w "mclist"
positionWindow $w

## Explanatory text
ttk::label $w.msg -font $font -wraplength 4i -justify left -anchor n -padding {10 2 10 6} -text "Ttk is the new Tk themed widget set. One of the widgets it includes is a tree widget, which can be configured to display multiple columns of informational data without displaying the tree itself. This is a simple way to build a listbox that has multiple columns. Clicking on the heading for a column will sort the data by that column. You can also change the width of the columns by dragging the boundary between them."
pack $w.msg -fill x

## See Code / Dismiss
pack [addSeeDismiss $w.seeDismiss $w] -side bottom -fill x

ttk::frame $w.container
ttk::treeview $w.tree -columns {country capital currency} -show headings \
    -yscroll "$w.vsb set" -xscroll "$w.hsb set"
ttk::scrollbar $w.vsb -orient vertical -command "$w.tree yview"
ttk::scrollbar $w.hsb -orient horizontal -command "$w.tree xview"
pack $w.container -fill both -expand 1
grid $w.tree $w.vsb -in $w.container -sticky nsew
grid $w.hsb         -in $w.container -sticky nsew
grid column $w.container 0 -weight 1
grid row    $w.container 0 -weight 1

image create photo upArrow -data {
    R0lGODlhDgAOAJEAANnZ2YCAgPz8/P///yH5BAEAAAAALAAAAAAOAA4AAAImhI+
    py+1LIsJHiBAh+BgmiEAJQITgW6DgUQIAECH4JN8IPqYuNxUAOw==}
image create photo downArrow -data {
    R0lGODlhDgAOAJEAANnZ2YCAgPz8/P///yH5BAEAAAAALAAAAAAOAA4AAAInhI+
    py+1I4ocQ/IgDEYIPgYJICUCE4F+YIBolEoKPEJKZmVJK6ZACADs=}
image create photo noArrow -height 14 -width 14

## The data we're going to insert
set data {
    Argentina		{Buenos Aires}		ARS
    Australia		Canberra		AUD
    Brazil		Brazilia		BRL
    Canada		Ottawa			CAD
    China		Beijing			CNY
    France		Paris			EUR
    Germany		Berlin			EUR
    India		{New Delhi}		INR
    Italy		Rome			EUR
    Japan		Tokyo			JPY
    Mexico		{Mexico City}		MXN
    Russia		Moscow			RUB
    {South Africa}	Pretoria		ZAR
    {United Kingdom}	London			GBP
    {United States}	{Washington, D.C.}	USD
}

## Code to insert the data nicely
set font [ttk::style lookup Heading -font]
foreach col {country capital currency} name {Country Capital Currency} {
    $w.tree heading $col -text $name -image noArrow -anchor w \
	-command [list SortBy $w.tree $col 0]
    $w.tree column $col -width [expr {
	[font measure $font $name] + [image width noArrow] + 5
    }]
}
set font [ttk::style lookup Treeview -font]
foreach {country capital currency} $data {
    $w.tree insert {} end -values [list $country $capital $currency]
    foreach col {country capital currency} {
	set len [font measure $font "[set $col]  "]
	if {[$w.tree column $col -width] < $len} {
	    $w.tree column $col -width $len
	}
    }
}

## Code to do the sorting of the tree contents when clicked on
proc SortBy {tree col direction} {
    # Determine currently sorted column and its sort direction
    foreach c {country capital currency} {
	set s [$tree heading $c state]
	if {("selected" in $s || "alternate" in $s) && $col ne $c} {
	    # Sorted column has changed
	    $tree heading $c -image noArrow state {!selected !alternate !user1}
	    set direction [expr {"alternate" in $s}]
	}
    }

# Build something we can sort
    set data {}
    foreach row [$tree children {}] {
	lappend data [list [$tree set $row $col] $row]
    }

set dir [expr {$direction ? "-decreasing" : "-increasing"}]
    set r -1

# Now reshuffle the rows into the sorted order
    foreach info [lsort -dictionary -index 0 $dir $data] {
	$tree move [lindex $info 1] {} [incr r]
    }

# Switch the heading so that it will sort in the opposite direction
    $tree heading $col -command [list SortBy $tree $col [expr {!$direction}]] \
	state [expr {$direction?"!selected alternate":"selected !alternate"}]
    if {[ttk::style theme use] eq "aqua"} {
	# Aqua theme displays native sort arrows when user1 state is set
	$tree heading $col state "user1"
    } else {
	$tree heading $col -image [expr {$direction?"upArrow":"downArrow"}]
    }
}

${this.title}

Code Editor : mclist.tcl